Installation

How to add the Ant file to external run configuration

• Double click on the Ant Build tree to create a new run configuration
• In the Main tab click on Browse Workspace and browse to the ant folder
  
• To run the Ant script click on the arrow next to the green play icon and toolbox and select your Ant script.
  

How to update the title?

	<!-- Project title -->
	<property name="project.title" value="Project Title | Page Source" />

How to exclude folders

	<!-- Folders to exclude -->
	<property name="exclude.folder.1" value="caurina" />
	<property name="exclude.folder.2" value="org" />
	<property name="exclude.folder.3" value="fl" />
	<property name="exclude.folder.4" value="nochump" />
	<property name="exclude.folder.5" value="com/blitzagency" />
	<property name="exclude.folder.6" value="com/wezside/framework" />

How to create a context menu item in Actionscript

private function setContextMenu():void
{
	var cmItemCopyright:ContextMenuItem = new ContextMenuItem( Version.COPYRIGHT, true, false );
	var cmItemBuild:ContextMenuItem = new ContextMenuItem( Version.BUILD_VERSION, false, false );
	var viewSrc:ContextMenuItem = new ContextMenuItem( "View Source", false, true );
	viewSrc.addEventListener( ContextMenuEvent.MENU_ITEM_SELECT, viewSrcClick );
	
	var cm:ContextMenu = new ContextMenu();
	cm.customItems = [viewSrc, cmItemCopyright, cmItemBuild ];
	cm.hideBuiltInItems();
	contextMenu = cm;			 
}

private function viewSrcClick( event:ContextMenuEvent ):void
{
	if ( event.target.caption == "View Source" )
		navigateToURL( new URLRequest( "viewsrc/" ));
}

Updating the colour scheme

• Open index.html in viewsrc/lib/
• Update the css href to css/index.css to load a darker scheme

Download the script here »

Example

The filter

Example

 
package com.wezside.filters 
{
	import flash.display.DisplayObject;
	import flash.display.Shader;
	import flash.display.Sprite;
	import flash.display.Stage;
	import flash.events.Event;
	import flash.filters.ShaderFilter;
	import flash.media.Video;
	import flash.net.NetConnection;
	import flash.net.NetStream;
	import flash.net.URLLoader;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLRequest;
	import flash.utils.getQualifiedClassName;		

	/**
	 * @author Wesley.Swanepoel
	 * 
	 * Compiler settings:
	 * -default-size 320 240 -default-frame-rate 31 -default-background-color 0x000000 -library-path {flexSDK}/frameworks/locale/en_US
	 */
	public class PixelBenderColourFilter extends Sprite 
	{

		
		private var video:Video;
		private var ns:NetStream;
		private var nc:NetConnection;
		private var colourFilter:ShaderFilter;
		private var shader:Shader;

		
		public function PixelBenderColourFilter() 
		{
			createVideoPlayer( ); 
			loadShader( );
			play( );
		}

		private function loadShader():void
		{
			var loader:URLLoader = new URLLoader( );
			loader.dataFormat = URLLoaderDataFormat.BINARY;
			loader.addEventListener( Event.COMPLETE, complete );
			loader.load( new URLRequest( "http://blog.wezside.co.za/examples/colourFilter/ColourFilter.pbj" ) );
		}

		private function complete( event:Event ):void 
		{
			shader = new Shader( event.target.data );
			addEventListener( Event.ENTER_FRAME, enterFrame );
		}

		private function enterFrame( event:Event ):void 
		{
			shader.data.center.value = [video.width / 2, video.height / 2];
			shader.data.vignetteInnerSize.value = [0.5];
			shader.data.vignetteOuterSize.value = [500];
			shader.data.saturation.value = [mouseX / stage.stageWidth * 2];
			shader.data.contrast.value = [mouseY / stage.stageHeight * 2];			
			colourFilter = new ShaderFilter( shader );
			video.filters = [ colourFilter ];
		}
		
		private function createVideoPlayer():void
		{
			nc = new NetConnection( );
			nc.client = new Object( );
			nc.connect( null );
			
			ns = new NetStream( nc );
			ns.client = {onCuePoint: cuePointHandler};
			ns.bufferTime = 6;
			
			video = new Video( 640, 292 );
			video.attachNetStream( ns );
			video.smoothing = true;
			addChild( video );
		}
		
		private function cuePointHandler( info:Object ):void
		{
			switch ( info.name )
			{
				case "Red"	 : shader.data.tintR.value = [0.3]; break;	
				case "Green" : shader.data.tintG.value = [0.5];break;	
				case "Blue"  : shader.data.tintB.value = [0.5];break;	
				case "exit"  : shader.data.tintR.value = [0.0];
							   shader.data.tintG.value = [0.0];
							   shader.data.tintB.value = [0.0];
							   break;	
				default		 : break;
			}
		}	
		
		public function play():void
		{
			ns.play( "flv/test.flv" );
		}

		override public function toString():String 
		{
			return getQualifiedClassName( this );
		}
	}
}

Resource

• http://labs.adobe.com/wiki/index.php/Pixel_Bender_Toolkit